****** Script para Conexao PPP ******
------------------------------8<------------ corte aqui.
#
# Exemplo.dip Shell para IP discado.
#
main:
# Primeiro vamos acertar nosso nome para a Internet.
# Eu sou, para o provedor local, "jcd.triang.com.br" (== 200.251.217.9)
# Note que meu IP e' fixo e existe esta maquina no DNS do meu provedor,
# se, no seu caso o IP for dinamico, comente a linha abaixo.
get $local jcd.triang.com.br
# Proximo passo, vamos acertar as coisas do HOST.
# A maquina que me atende, no caso o roteador, eu chamo de 'dialup'
# (== 200.251.217.239). No caso, o cliente (meu computador) pega este
# numero no arquivo /etc/hosts.
get $remote dialup
# Nossa netmask para sl0: 255.255.255.0
netmask 255.255.255.0
# Agora as coisas do MODEM
# Vamos setar a porta e a velocidade.
# Se a porta for a com2 (do DOS) por exemplo:
port cua1
speed 38400
# Resetando o MODEM e o terminal.
# Isto nao funciona, nao sei porque. Em todo caso experimente!
# reset
# Agora vamos discar.
send ATZ4\r
wait OK 2
send ATZ4\r
wait OK 2
# Se sua linha for muito ruim, tire o comentario das duas linhas abaixo.
# send ATS38=12\r
# wait OK 2
# Substitua os noves pelo numero a ser discado.
send ATX4DT9999999\r
# Se tudo correu bem, estamos conectados. Agora as coisas de login.
login:
sleep 2
wait ogin: 30
if $errlvl != 0 goto login_error
# Substitua 'meulogin' pelo seu. :))
send meulogin\n
wait ord: 30
if $errlvl != 0 goto password_error
# Substitua 'segredo' pelo seu passwd.
send segredo\n
loggedin:
# Finalmente estamos logados.
wait ing.... 15
if $errlvl != 0 goto prompt_error
# Vamos acertar os parametros para esta conexao PPP.
# Cheque com o seu provedor qual e' o MTU (Max. Transfer Unity) que ele usa.
get $mtu 1500
# Vamos certificar que "route add -net default jcd.triang.com.br" sera'
# estabelecido.
default
# Finalmente mostre nosso IP e cai fora (do script, claro)!
done:
print CONNECTED $locip ---> $rmtip
mode PPP
goto exit
prompt_error:
print TIME-OUT waiting for SLIPlogin to fire up...
goto error
login_error:
print Trouble waiting for the Login: prompt...
goto error
password_error:
print Trouble waiting for the Password: prompt...
goto error
error:
print CONNECT FAILED to $remote
quit 1
exit:
exit
------------------------------>8-------- corte aqui.
Tenha bom proveito.